~iany/ X

让 Windows 输入法的语音快捷键在英文键盘下也能触发

me@iany.me (Ian Yang) — Wed, 23 Sep 2026 00:45:26 +0800

我平时用英文键盘布局写代码，想说句话就得先切到中文输入法。我希望按 RAlt + Space 就能直接开始语音输入。

一开始我以为输入法的语音快捷键只在中文布局下才生效。后来发现，微信输入法只要激活过，就会注册一个真正的全局快捷键，切回英文也能触发。但这时它没有权限往当前窗口插入文本，只能把识别的文字放到剪贴板，还得自己粘贴一下。

我本来就在用 AutoHotkey，比如之前分享过解决 Windows 中文输入法下 Shift + Space 快捷键的困扰。于是想让脚本先切到中文，再转发语音快捷键。但是微信输入法的全局快捷键优先级比 AutoHotkey 高。

解决办法是把两组快捷键分开：RAlt + Space 留给 AutoHotkey，微信输入法改用 RWin + RAlt + Space。平时只按前一组，切换布局和转发都交给脚本。

TL;DR

先把微信输入法里「开启和结束语音输入」的快捷键改成 RWin + RAlt + Space。

下面的 AutoHotkey v2 脚本的效果是：英文布局下按 RAlt + Space，自动切到中文输入法并触发语音；再按一次结束，等语音面板关闭后切回英文。原本就在中文布局下，则只转发开启和结束的快捷键，不切换布局。

$>!Space::{
static panel := "语音输入 ahk_class wetype.flutter.setting"
static restoreHKL := 0
ending := WinExist(panel)
KeyWait "Space"
KeyWait "RAlt"
if ending {
Send "{RAlt down}{RWin down}{Space}{RWin up}{RAlt up}"
if WinWaitClose(panel, , 3) {
if restoreHKL
ApplyHKL(restoreHKL)
restoreHKL := 0
}
return
}
restoreHKL := 0
prev := ForegroundHKL()
if !ChineseIMEActive() {
ActivateIME("00000804")
deadline := A_TickCount + 1000
while !ChineseIMEActive() && A_TickCount < deadline
Sleep 20
if !ChineseIMEActive()
return
if (prev & 0x3FF) = 0x09
restoreHKL := prev
}
Sleep 100
Send "{RAlt down}{RWin down}{Space}{RWin up}{RAlt up}"
}
ChineseIMEActive() => (ForegroundHKL() & 0xFFFF) = 0x0804
ForegroundHKL() {
hwnd := DllCall("GetForegroundWindow", "ptr")
tid := DllCall("GetWindowThreadProcessId", "ptr", hwnd, "ptr", 0, "uint")
return DllCall("GetKeyboardLayout", "uint", tid, "ptr")
}
ActivateIME(klid) {
if hkl := DllCall("LoadKeyboardLayout", "str", klid, "uint", 0x101, "ptr")
ApplyHKL(hkl)
}
ApplyHKL(hkl) {
hwnd := DllCall("GetForegroundWindow", "ptr")
tid := DllCall("GetWindowThreadProcessId", "ptr", hwnd, "ptr", 0, "uint")
me := DllCall("GetCurrentThreadId", "uint")
DllCall("AttachThreadInput", "uint", me, "uint", tid, "int", 1)
DllCall("ActivateKeyboardLayout", "ptr", hkl, "uint", 0)
DllCall("AttachThreadInput", "uint", me, "uint", tid, "int", 0)
PostMessage 0x0050, 0, hkl, , "ahk_id " hwnd
}

两组快捷键分工

RAlt + Space 是给自己按的，RWin + RAlt + Space 是给脚本发的。这样脚本就有机会先处理布局，再通知微信输入法。

KeyWait "Space"
KeyWait "RAlt"
Send "{RAlt down}{RWin down}{Space}{RWin up}{RAlt up}"

先等手上的按键松开，再完整发送另一组组合键，避免物理按键和模拟按键混在一起。

中文状态下也不能再用 #HotIf 跳过整个热键了，因为微信输入法已经不认原来的组合键。现在中英文都由脚本接管，只在需要时切换布局。

切换输入法

切换用三件套。LoadKeyboardLayout 拿到 HKL，再通过 AttachThreadInput 把自己挂到前台线程上、调 ActivateKeyboardLayout，最后补一个 WM_INPUTLANGCHANGEREQUEST：

DllCall("AttachThreadInput", "uint", me, "uint", tid, "int", 1)
DllCall("ActivateKeyboardLayout", "ptr", hkl, "uint", 0)
DllCall("AttachThreadInput", "uint", me, "uint", tid, "int", 0)
PostMessage 0x0050, 0, hkl, , "ahk_id " hwnd

ActivateKeyboardLayout 单独调只对自己的线程生效，所以必须先 AttachThreadInput。

要注意 HKL 层面分不出具体是哪个中文输入法：微软拼音、微信输入法、豆包的 langid 都是 0x0804，切过去的是上次用的那个。所以判断是否已经是中文，比较低 16 位就够了：

ChineseIMEActive() => (ForegroundHKL() & 0xFFFF) = 0x0804

切换是异步的，PostMessage 发完不代表已经生效，所以要轮询等到真的切过去。脚本最多等一秒，没切成功就直接返回，不再发送语音快捷键；成功后再留 100 毫秒缓冲。

语音结束后切回英文

既然是英文布局下触发的，说完话自然应该回到英文。现在用同一个快捷键开启和结束，就可以在第二次按键时处理切回，不用从开始录音起一直等着。

微信输入法的语音面板是一个独立的顶层窗口。每次按键先用 WinExist 看它在不在：不在就是开始，在就是结束。找窗口类名的办法是写个脚本记录一段时间内新出现的所有窗口，然后去触发一次语音：

class=wetype.flutter.setting
title=语音输入
exe=wetype_update.exe

开始时用 static restoreHKL 记住要恢复的布局，但只记英文：(prev & 0x3FF) = 0x09 判断的是主语言 ID，不限于某一种英文布局。原本就是中文则不记录，也就不会在结束后多切一次。

结束时先发快捷键，再等面板关闭：

if ending {
Send "{RAlt down}{RWin down}{Space}{RWin up}{RAlt up}"
if WinWaitClose(panel, , 3) {
if restoreHKL
ApplyHKL(restoreHKL)
restoreHKL := 0
}
return
}

最多等三秒。面板还没关就不切，避免在语音还没结束时抢先换掉输入法。这个版本只在再次按 RAlt + Space 结束时恢复布局；如果用鼠标关闭面板，不会自动切回。

类名和标题是从微信输入法 2.1.4.6 抓的，升级后可能变。真变了，脚本就分不清是在开启还是结束语音，自动切回也会失效，需要重新确认窗口信息。

解决 Windows 中文输入法下 Shift + Space 快捷键的困扰

me@iany.me (Ian Yang) — Wed, 10 Apr 2024 19:32:40 +0800

最近我把主要的工作环境转移到了Windows系统。之前 Windows 最困扰我的是 Shift + Space 的快捷键。在中文输入法状态下稍微打字快一点，就会误触发切换半角全角的功能，打乱输入的节奏。既然我决定长期使用 Windows 系统，就花了一些时间全面解决了这个问题。

TL;DR

安装 AutoHotkey v2 版。将以下代码加入到一个 .ahk 为后缀的文件中，比如“文档”目录中的 main.ahk 文件:

<+Space::Send (A_PriorKey = "LShift" ? "+{Space}" : "{Blind}{Shift up}{Space}{Shift down}{LWin}")
>+Space::Send (A_PriorKey = "RShift" ? "+{Space}" : "{Blind}{Shift up}{Space}{Shift down}{LWin}")

双击文件 main.ahk 即可生效，如果要启动时自动生效，可以为这个文件创建一个快捷方式，然后将快捷方式移到到“启动”目录中。可以通过以下办法快速打开“启动”目录。

使用快捷键 Win + r 打开运行窗口
输入 shell:startup 并使用 Enter 确认

思路说明

Shift + Space 烦人的地方在于它会吞掉本想输入的空格。输入需要 Shift 组合键的符号时，通常在前或者在后要加上空格，比如 :(){} 这些符号。如果输入速度很快，很可能会在 Shift 尚未完全松开时按下 Space ，这时候没有输入空格反而是切换了半角全角，如果当前需要使用半角，还得再按一次切换回来。

基于上述分析，我想实现在按下 Shift 键后，如果在按下空格键之前按下了其他键，便视为 Shift 键没有及时松开，应该输入一个空格符号。如果在按下 Shift 键后立即按下空格键，应保留原来的半角全角切换功能。这样的配置不但能避免误触发，还可以被利用来快速输入 ) { 这样的序列，因为全程 Shift 不用松开了。

上面的 AutoHotkey 代码即实现了这里描述的功能。

代码说明

代码有两行，分别对应的左右手 Shift 触发的情况。我尝试过合并成一条但失败了，具体原因我也不清楚，也不知道为什么分开就能工作了。

下面以左手的第一行为例说明：

<+Space::Send (A_PriorKey = "LShift" ? "+{Space}" : "{Blind}{Shift up}{Space}{Shift down}{LWin}")

AutoHotkey 代码	说明
`<+Space::`	为 `Shift` + `Space` 设置命令，并只有使用左手的 `Shift` 才能触发。
`Send`	发送指定的按键序列。
`(A_PriorKey = "LShift" ? X : Y)`	如果变量 `A_PriorKey` 的值等于 `LShift` 时返回 X 否则返回 Y。
`+{Space}`	发送组合按键 `Shift` + `Space` 以触发其原本的功能，即切换半角全角。
`{Blind}{Shift up}{Space}{Shift down}{LWin}`	这么一大串其实只是为了实现在 AutoHotkey 里在 `Shfit` 按下的情况下输入一个空格符号。

第一个比较重要的点是自动变量 A_PriorHotkey。它记录的是组合键所有键被按下之前上一个按键状态有变化的键。因为组合键最后一个按下的一定是非修饰键，所以如果按下 Shift 后立即按下 Space，A_PriorHotkey 就是 LShift 或者 RShift。相反，如果 A_PriorHotkey 等于其它值就表示按下 Shift 到按下 Space 之间有按过其它按键。

第二个点是用来模拟输入空格的一长串 {Blind}{Shift up}{Space}{Shift down}{LWin}

{Blind} 的作用是让 {Shift up} 强制修改 Shift 的状态改为松开保证后面 {Space} 输入一个空格符号。
{Shift down} 是恢复 Shift 按下的状态，这样后面可以继续输入还 Shift 的组合键。
{LWin} 不会触发任何操作。它的作用是如果在中文输入法里启用了点按 Shift 来切换中英文，在下面的按键序列中会正确输入 : (冒号+空格) 并且不会误触发中英文切换：
- 按下 Shift
- 按下 :
- 松开 :
- 按下 Space
- 松开 Space
- 松开 Shift